Cellbender empty droplet removal

subworkflows/nf-core/h5ad_removebackground_barcodes_cellbender_anndata/main.nf

@@ -0,0 +1,28 @@
+//
+// Apply cellbender and anndata to h5ad for background and empty droplet removal
+//
+include { CELLBENDER_REMOVEBACKGROUND } from '../../../modules/nf-core/cellbender/removebackground'
+include { ANNDATA_BARCODES            } from '../../../modules/nf-core/anndata/barcodes'
+
+workflow H5AD_REMOVEBACKGROUND_BARCODES_CELLBENDER_ANNDATA {
+
+    take:
+    ch_unfiltered // channel: [mandatory] meta, h5ad
+
+    main:
+    ch_versions = Channel.empty()
+
+    CELLBENDER_REMOVEBACKGROUND(ch_unfiltered)
+    ch_versions = ch_versions.mix(CELLBENDER_REMOVEBACKGROUND.out.versions)
+
+    ch_combined = ch_unfiltered.join(CELLBENDER_REMOVEBACKGROUND.out.barcodes)
+
+    ANNDATA_BARCODES(ch_combined)
+    ch_versions = ch_versions.mix(ANNDATA_BARCODES.out.versions)
+
+    emit:
+    h5ad = ANNDATA_BARCODES.out.h5ad  // channel: [ val(meta), path(h5ad) ]
+
+    versions = ch_versions  // channel: [ path(versions.yml) ]
+}
+

subworkflows/nf-core/h5ad_removebackground_barcodes_cellbender_anndata/meta.yml

@@ -0,0 +1,35 @@
+name: "h5ad_removebackground_barcodes_cellbender_anndata"
+description: Use features of Cellbender to remove background noise and empty droplet
+keywords:
+  - scdownstream
+  - cellbender
+  - anndata
+components:
+  - cellbender/removebackground
+  - anndata/barcodes
+input:
+  - ch_unfiltered:
+      type: file
+      description: |
+        The input channel containing the unfiltered AnnData file to process
+        and remove background noise and empty droplets
+        Structure: [ val(meta), path(h5ad) ]
+      pattern: "*.h5ad"
+output:
+  - h5ad:
+      description: |
+        Background and empty droplet removed AnnData file containing cells with
+        barcodes exceeding 0.5 posterior cell probability determined by the
+        cellbender's remove-background
+        Structure: [ val(meta), path(h5ad) ]
+      pattern: "*.h5ad"
+  - versions:
+      type: file
+      description: |
+        File containing software versions
+      pattern: "versions.yml"
+authors:
+  - "@nictru"
+  - "@chaochaowong"
+maintainers:
+  - "@nictru"

subworkflows/nf-core/h5ad_removebackground_barcodes_cellbender_anndata/tests/epochs.config

@@ -0,0 +1,6 @@
+
+process {
+    withName: CELLBENDER_REMOVEBACKGROUND {
+        ext.args = '--epochs 20'
+    }
+}

subworkflows/nf-core/h5ad_removebackground_barcodes_cellbender_anndata/tests/main.nf.test

@@ -0,0 +1,32 @@
+nextflow_workflow {
+
+    name "Test Subworkflow H5AD_REMOVEBACKGROUND_BARCODES_CELLBENDER_ANNDATA"
+    script "../main.nf"
+    workflow "H5AD_REMOVEBACKGROUND_BARCODES_CELLBENDER_ANNDATA"
+
+    tag "subworkflows"
+    tag "subworkflows_nfcore"
+    tag "subworkflows/h5ad_removebackground_barcodes_cellbender_anndata"
+    tag "cellbender/removebackground"
+    tag "anndata/barcodes"
+
+    test("h5ad - h5ad_removebackground_barcodes_cellbender_anndata") {
+        config './epochs.config'
+        when {
+            workflow {
+                """
+                input[0] = Channel.of([
+                    [ id:'test' ], // meta map
+                    file("https://raw.githubusercontent.com/nf-core/test-datasets/scdownstream/samples/SAMN14430799_raw_matrix_5k.h5ad", checkIfExists: true)
+                ])
+                """
+            }
+        }
+        then {
+            assertAll(
+                { assert workflow.success},
+                { assert snapshot(workflow.out).match()}
+            )
+        }
+    }
+}

subworkflows/nf-core/h5ad_removebackground_barcodes_cellbender_anndata/tests/main.nf.test.snap

@@ -0,0 +1,37 @@
+{
+    "h5ad - h5ad_removebackground_barcodes_cellbender_anndata": {
+        "content": [
+            {
+                "0": [
+                    [
+                        {
+                            "id": "test"
+                        },
+                        "test.h5ad:md5,6c94663b900a495d3492cd0b216c9b67"
+                    ]
+                ],
+                "1": [
+                    "versions.yml:md5,3b268371ecd09ac624398c004f5e279d",
+                    "versions.yml:md5,fc7f5fec60cfd2b10b91177571ee63e8"
+                ],
+                "h5ad": [
+                    [
+                        {
+                            "id": "test"
+                        },
+                        "test.h5ad:md5,6c94663b900a495d3492cd0b216c9b67"
+                    ]
+                ],
+                "versions": [
+                    "versions.yml:md5,3b268371ecd09ac624398c004f5e279d",
+                    "versions.yml:md5,fc7f5fec60cfd2b10b91177571ee63e8"
+                ]
+            }
+        ],
+        "meta": {
+            "nf-test": "0.9.0",
+            "nextflow": "24.10.1"
+        },
+        "timestamp": "2024-11-26T15:17:04.577770824"
+    }
+}